ForNext

PlayList を新規追加して WAVE ファイルをインポート

VBScript

Set iTunesApp = WScript.CreateObject("iTunes.Application")

WScript.StdOut.WriteLine "登録開始..."
WScript.StdOut.WriteLine  iTunesApp.CurrentEncoder.Name

Set playList = iTunesApp.LibrarySource.Playlists.ItemByName("新しいプレイリスト")
If playList Is Nothing Then
    Set playList = iTunesApp.CreatePlayList("新しいプレイリスト")
End If

Set sts = iTunesApp.ConvertFile("c:\WAV\01 矢沢永吉\01 キャロル\01 ルイジアンナ\02 ヘイ・タクシー.wav")
Do While (sts.InProgress)
    WScript.Sleep 1000
Loop

For Each track In sts.Tracks
    track.Artist       = "キャロル"
    track.Album        = "ルイジアンナ"
    track.TrackNumber  = "2"
    track.Name         = "02 ヘイ・タクシー"
    track.Composer     = "ジョニー大倉 & 矢沢永吉"
    playList.AddTrack(track)
Next
Set sts       = Nothing

For Each track In playList.Tracks
    WScript.StdOut.Write      track.Artist       & ","
    WScript.StdOut.Write      track.Album        & ","
    WScript.StdOut.Write      track.TrackNumber  & ","
    WScript.StdOut.Write      track.Name         & ","
    WScript.StdOut.Write      track.Duration     & ","
    WScript.StdOut.Write      track.Composer     & ","
    WScript.StdOut.Write      track.Bitrate
    WScript.StdOut.WriteLine
Next

iTunesApp.Quit
Set iTunesApp = Nothing

WScript.StdOut.WriteLine "登録終了"

C:\>cscript //nologo itunes5.vbs
登録開始...
MP3 Encoder
登録終了
キャロル,ルイジアンナ,2,02 ヘイ・タクシー,141,ジョニー大倉 & 矢沢永吉,192

JScript

Perl

PHP

Python

Ruby

PowerShell

Scala

F#

C

C++

C++Builder

VC++

C#

Java

Objective-C

D

VB

VB.NET

Delphi

Ada

PL/SQL

T-SQL